Servomoteur Faller ou autre

Mode d'emploi Commande Pont Secteur Faller

1 Avant la mise sous tension
- vérifier que les 3 interrupteurs BP1 BP2 et BP3 sont sur Arrêt.

2 Après la mise sous tension
 - le servo moteur se positionne rapidement en position voie MEDIANE.
 S'il ne bouge pas c'est qu'il se trouvait déjà dans cette position.
 Si un décalage est visible entre le pont et la voie d'entrée, consulter 4.2 Réglage position MEDIANE.

3 Sélection d'une voie
 3.1 Sélection de la voie MAXI
 - basculer l'interrupteur BP1 sur Marche. Le pont commence à tourner vers la voie MAXI.
     Si la vitesse est trop lente ou trop rapide, consulter 4.1 Réglage vitesse.
        Dès qu'il atteint la position voie MAXI, il s'arrête et la led s'allume. Basculer l'interrupteur BP1 sur Arrêt.
 Si un décalage est visible entre le pont et la voie MAXI, consulter 4.3 Réglage position MAXI.

 3.2 Sélection de la voie MINI
 - basculer l'interrupteur BP2 sur Marche. Le pont commence à tourner vers la voie MINI.
 Dès qu'il atteint la position voie MINI, il s'arrête et la led s'allume. Basculer l'interrupteur BP2 sur Arrêt.
 Si un décalage est visible entre le pont et la voie MINI, consulter 4.4 Réglage position MINI.

3.3 Sélection de la voie MEDIANE
3.3.1 le pont est en position voie MAXI
- basculer les interrupteurs BP2 et BP3 sur Marche.
 Le pont quitte la position voie MAXI et se dirige vers la position voie MEDIANE.
 Dès qu'il atteint la position voie MEDIANE, il s'arrête et la led s'allume. Basculer les interrupteurs BP2 et BP3 sur Arrêt.
 Si BP2 est laissé sur Marche, le pont reprend sa rotation vers la position voie MINI, s'arrête sur la position voie MINI et La led s'allume.

3.3.2 le pont est en position voie MINI
- basculer les interrupteurs BP1 et BP3 sur Marche.
 Le pont quitte la position voie MINI et se dirige vers la position voie MEDIANE.
 Dès qu'il atteint la position voie MEDIANE, il s'arrête et la led s'allume. Basculer les interrupteurs BP1 et BP3 sur Arrêt.
 Si BP3 est laissé sur Marche, le pont reprend sa rotation vers la position voie MAXI, s'arrête sur la position voie MAXI et La led s'allume.

4 Réglages
4.1 Réglage vitesse
- basculer soit l'interrupteur BP1 soit BP2 sur Marche.
 Dès que le pont commence à se déplacer, agir sur R1 avant que la led s'allume.

4.2 Réglage position MEDIANE
- basculer soit les interrupteurs BP1 et BP3 soit BP2 et BP3 sur Marche.
 Dès que la led s'allume, agir sur R2 par petites variations, le pont va se déplacer et la led va se rallumer.
 Quand la position est correcte, le réglage est terminé.
 Couper l'alimentation, remettre l'alimentation, le pont va positionner sur la nouvelle position MEDIANE

4.3 Réglage position MAXI
- basculer l'interrupteur BP1 sur Marche.
 Dès que la led s'allume, agir sur R3 par petites variations, le pont va se déplacer et la led va se rallumer.
 Quand la position est correcte, le réglage est terminé.
 
4.4 Réglage position MINI
- basculer l'interrupteur BP1 sur Marche.
 Dès que la led s'allume, agir sur R4 par petites variations, le pont va se déplacer et la led va se rallumer.
 Quand la position est correcte, le réglage est terminé.

/*arduino servo 3BP reglages
  gestion d'un servomoteur pour animer un pont secteur Faller
  code compatible Attiny84 du fait de l'utilisation
  de la bibliothèque SoftRcPulseOut.h  
  17/06/2021
  Fantasio
  test: ok sur Nano
  Réglage de la position médiane et des deux positions de sortie
  Pour une commande en microsecondes:  1472 centré   544 mini   2400 maxi
  Réglage de la vitesse
  Arrêt automatique sur les trois positions sélectionnées
  Quand la position sélectionnée est atteinte la led s'allume.
  (Utile lors des réglages de position)

  Position des inters
  (un inter sur Marche envoie un niveau 0, sur Arrêt un niveau 1)
  BP1      BP2      BP3       Action
  Marche   Marche   Marche  aucun mouvement
  Marche   Marche   Arrêt   aucun mouvement
  Marche   Arrêt    Marche  sélection position médiane en allant vers position maxi
  Marche   Arrêt    Arrêt   sélection position maxi
  Arrêt    Marche   Marche  sélection position médiane en allant vers position min
  Arrêt    Marche   Arrêt   sélection position mini
  Arrêt    Arrêt    Marche  aucun mouvement
  Arrêt    Arrêt    Arrêt   aucun mouvement

              Brochage Attiny84

             VCC=|1  U 14|= GND
                =|2    13|= A0 POTAR_VITESSE
                =|3    12|= A1 POTAR_MEDIANE
                =|4    11|= A2 POTAR_MAXI
                =|5    10|= A3 POTAR_MINI
       LED pin7 =|6     9|= pin4 BP1
       BP3 pin6 =|7     8|= pin5 BP2
*/

#include <SoftRcPulseOut.h>
#include <Rcul.h>
SoftRcPulseOut monServo; //objet Servo
const byte BP1 = 4; // interrupteur pour aller à la position maxi
const byte BP2 = 5; // interrupteur pour aller à la position mini
const byte BP3 = 6; // interrupteur pour aller à la position médiane
const byte LED = 13; // indique que la position sélectionnée est atteinte
// const byte LED = 7; // pour version Attiny84
const byte POTAR_VITESSE = A0; // réglage de la vitesse de déplacement
const byte POTAR_MEDIANE = A1; // réglage de la position médiane
const byte POTAR_MAXI = A2;    // réglage de la position maxi
const byte POTAR_MINI = A3;    // réglage de la position maxi

int position;               // pour calcul du déplacement
int selectionPosition;  // prend la valeur de la position sélectionnée par les BP
int positionMediane = 1472; // position de départ
int positionMaxi = 2400;    // première position
int positionMini = 560;     // seconde position
int tempo = 35;             // permet de régler la vitesse de déplacement

void setup() {
  pinMode(BP1, INPUT_PULLUP); // basculé sur Marche il envoie une masse
  pinMode(BP2, INPUT_PULLUP);
  pinMode(BP3, INPUT_PULLUP);
  pinMode(LED, OUTPUT);
  monServo.attach(2); // Attache le servomoteur à la broche 2
  positionMediane = analogRead(POTAR_MEDIANE); // Lecture de la valeur du potentiomètre MEDIANE
  positionMediane = map(positionMediane, 0, 1023, 1000, 2000); // Calibrage des valeurs
  position = positionMediane; // au démarrage le servo est en position médiane
  monServo.write_us(position); // le servo prend la position médiane et attend les commandes
} // fin setup

void loop() {
  SoftRcPulseOut::refresh();
  tempo = analogRead(POTAR_VITESSE); // Lecture de la valeur du potentiomètre VITESSE
  tempo = map(tempo, 0, 1023, 1, 35); // Calibrage des valeurs
  positionMediane = analogRead(POTAR_MEDIANE); // Lecture de la valeur du potentiomètre MEDIANE
  positionMediane = map(positionMediane, 0, 1023, 1000, 2000); // Calibrage des valeurs
  positionMaxi = analogRead(POTAR_MAXI); // Lecture de la valeur du potentiomètre MAXI
  positionMaxi = map(positionMaxi, 0, 1023, 1600, 2400); // Calibrage des valeurs
  positionMini = analogRead(POTAR_MINI); // Lecture de la valeur du potentiomètre MINI
  positionMini = map(positionMini, 0, 1023, 560, 1400); // Calibrage des valeurs

  if (digitalRead(BP1) == LOW && digitalRead(BP2) == HIGH) { // Si BP1 sur Marche mais pas BP2
    if (digitalRead(BP3) == LOW) {                           // Si BP3 également sur Marche
      selectionPosition = positionMediane;                   // alors arrêt en position MEDIANE selectionné
    }
    else {
      selectionPosition = positionMaxi; // Sinon arrêt en position MAXI sélectionné
    }
    monServo.attach(2);
    monServo.write_us(position);
    position = position + 1;            // On augmente la valeur de l'angle
    if (position > selectionPosition) { // Si la position sélectionnée est atteinte
      position = selectionPosition;     // alors le servo s'arrête
      digitalWrite(LED, HIGH);          // et on prévient l'opérateur
      monServo.detach();
    }
    else {
      digitalWrite(LED, LOW); // Tant que la position sélectionnée n'est pas atteinte la led reste éteinte
    }
    delay(tempo);
    SoftRcPulseOut::refresh();
  } // fin BP1

  if (digitalRead(BP1) == HIGH && digitalRead(BP2) == LOW) { // Si BP2 sur Marche mais pas BP1
    if (digitalRead(BP3) == LOW) {                           // Si BP3 également sur Marche
      selectionPosition = positionMediane;                   // alors arrêt en position MEDIANE selectionné
    }
    else {
      selectionPosition = positionMini; // Sinon arrêt en position MINI sélectionné
    }
    monServo.attach(2);
    monServo.write_us(position);
    position = position - 1;            // On diminue la valeur de l'angle
    if (position < selectionPosition) { // Si la position sélectionnée est atteinte
      position = selectionPosition;     // alors le servo s'arrête
      digitalWrite(LED, HIGH);          // et on prévient l'opérateur
      monServo.detach();
    }
    else {
      digitalWrite(LED, LOW); // Tant que la position sélectionnée n'est pas atteinte la led reste éteinte
    }
    delay(tempo);
    SoftRcPulseOut::refresh();
  } // fin BP2
} // fin loop