Faire sa propre centrale DCC

[code]programme avec indentations et sauts de lignes.[/code]

// RFID reader ID-12 for Arduino
// Based on code by BARRAGAN <http://people.interaction-ivrea.it/h.barragan>
// and code from HC Gilje - http://hcgilje.wordpress.com/resources/rfid_id12_tagreader/
// Modified for Arudino by djmatic
// Modified for ID-12 and checksum by Martijn The - http://www.martijnthe.nl/
//
// Use the drawings from HC Gilje to wire up the ID-12.
// Remark: disconnect the rx serial wire to the ID-12 when uploading the sketch
//
// Source: http://arduino.cc/playground/Code/ID12

void setup() {
  Serial.begin(9600);                                // connect to the serial port
}

void loop () {
  byte i = 0;
  byte val = 0;
  byte code[6];
  byte checksum = 0;
  byte bytesread = 0;
  byte tempbyte = 0;

  if(Serial.available() > 0) {
    if((val = Serial.read()) == 2) {                  // check for header
      bytesread = 0;
      while (bytesread < 12) {                        // read 10 digit code + 2 digit checksum
        if( Serial.available() > 0) {
          val = Serial.read();
          if((val == 0x0D)||(val == 0x0A)||(val == 0x03)||(val == 0x02)) { // if header or stop bytes before the 10 digit reading
            break;                                    // stop reading
          }

          // Do Ascii/Hex conversion:
          if ((val >= '0') && (val <= '9')) {
            val = val - '0';
          } else if ((val >= 'A') && (val <= 'F')) {
            val = 10 + val - 'A';
          }

          // Every two hex-digits, add byte to code:
          if (bytesread & 1 == 1) {
            // make some space for this hex-digit by
            // shifting the previous hex-digit with 4 bits to the left:
            code[bytesread >> 1] = (val | (tempbyte << 4));

            if (bytesread >> 1 != 5) {                // If we're at the checksum byte,
              checksum ^= code[bytesread >> 1];      // Calculate the checksum... (XOR)
            };
          } else {
            tempbyte = val;                          // Store the first hex digit first...
          };

          bytesread++;                                // ready to read next digit
        }
      }

      // Output to Serial:

      if (bytesread == 12) {                          // if 12 digit read is complete
        Serial.print("5-byte code: ");
        for (i=0; i<5; i++) {
          if (code[i] < 16) Serial.print("0");
          Serial.print(code[i], HEX);
          Serial.print(" ");
        }
        Serial.println();

        Serial.print("Checksum: ");
        Serial.print(code[5], HEX);
        Serial.println(code[5] == checksum ? " -- passed." : " -- error.");
        Serial.println();
      }

      bytesread = 0;
    }
  }
}

/* Détection de trains par TAGS RFID */
#define VERSION "Détection de trains - V0.1 - 5 Mars 2013"

int RFIDResetPin = 13; // la pin 13 Arduino est reliée à la broche 2 (RST) de l'ID12

//Liste des tags RFID (5 octets + Checksum)
char tag1[13] = "004D8BB1CEB9";
char tag2[13] = "004D8BB22357";
char tag3[13] = "004D8BB1B6C1";
char tag4[13] = "004D8BB2384C";
char tag5[13] = "004D8BB1A2D5";

void setup(){
 Serial.begin(9600);

 pinMode(RFIDResetPin, OUTPUT);
 digitalWrite(RFIDResetPin, HIGH);

 //on peut brancher des leds + 1KR sur ces pins
 pinMode(2, OUTPUT);
 pinMode(3, OUTPUT);
 pinMode(4, OUTPUT);
 pinMode(5, OUTPUT);
 pinMode(6, OUTPUT);
 
 delay(500);
 Serial.println(VERSION);
}

void loop(){

 char tagString[13];
 int index = 0;
 boolean reading = false;

 while(Serial.available()){

  int readByte = Serial.read(); //lecture de l'octet suivant

  if(readByte == 2) reading = true; //debut de tag
  if(readByte == 3) reading = false; //fin de tag

  if(reading && readByte != 2 && readByte != 10 && readByte != 13){
    //enregistrement du tag
    tagString[index] = readByte;
    index ++;
  }
 }

 checkTag(tagString); //test de correspondance avec les tags attendus
 clearTag(tagString); //effacement
 resetReader(); //reset du lecteur RFID ID12
}

void checkTag(char tag[]){
///////////////////////////////////
//Test du tag par rapport aux valeurs pré-enregistrés
///////////////////////////////////

 if(strlen(tag) == 0) return; //vide : retour

 if(compareTag(tag, tag1)){ // si le tag est reconnu
  lightLED(2);
  Serial.println("loco 1 - AAAAAA");

 }else if(compareTag(tag, tag2)){ //if matched tag2, do this
  lightLED(3);
  Serial.println("loco 2 - BBBBBB");

 }else if(compareTag(tag, tag3)){
  lightLED(4);
  Serial.println("loco 3 - CCCCCC");

 }else if(compareTag(tag, tag4)){
  lightLED(5);
  Serial.println("loco 4 - DDDDDD");

 }else if(compareTag(tag, tag5)){
  lightLED(6);
  Serial.println("loco 5 - EEEEEE");

 }else{
  Serial.println(tag); //sinon, affiche la valeur non reconnue
 }

}

void lightLED(int pin){
///////////////////////////////////
//Allume une Led pendant 250ms
///////////////////////////////////

 digitalWrite(pin, HIGH);
 delay(250);
 digitalWrite(pin, LOW);
}

void resetReader(){
///////////////////////////////////
//Reset du lecteur RFID pret pour une nouvelle lecture.
///////////////////////////////////
 digitalWrite(RFIDResetPin, LOW);
 digitalWrite(RFIDResetPin, HIGH);
 delay(150);
}

void clearTag(char one[]){
///////////////////////////////////
//effacement par écriture de ASCII 0 pour éviter une fausse reconnaissance
///////////////////////////////////
 for(int i = 0; i < strlen(one); i++){
  one[i] = 0;
 }
}

boolean compareTag(char one[], char two[]){
///////////////////////////////////
//comparaison de 2 tags
///////////////////////////////////

 if(strlen(one) == 0) return false; //vide

 for(int i = 0; i < 12; i++){
  if(one[i] != two[i]) return false;
 }

 return true; //valide
}